summaryrefslogtreecommitdiff
path: root/lib/Travel/Status/DE/URA/Result.pm
blob: 2c13461d4941f26a51ea13504c0fe081c0d1a5ab (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
package Travel::Status::DE::URA::Result;

use strict;
use warnings;
use 5.010;

use parent 'Class::Accessor';

use DateTime::Format::Duration;

our $VERSION = '0.03';

Travel::Status::DE::URA::Result->mk_ro_accessors(
	qw(datetime destination line line_id stop stop_id));

sub new {
	my ( $obj, %conf ) = @_;

	my $ref = \%conf;

	return bless( $ref, $obj );
}

sub countdown {
	my ($self) = @_;

	$self->{countdown} //= $self->datetime->subtract_datetime( $self->{dt_now} )
	  ->in_units('minutes');

	return $self->{countdown};
}

sub countdown_sec {
	my ($self) = @_;
	my $secpattern = DateTime::Format::Duration->new( pattern => '%s' );

	$self->{countdown_sec} //= $secpattern->format_duration(
		$self->datetime->subtract_datetime( $self->{dt_now} ) );

	return $self->{countdown_sec};
}

sub date {
	my ($self) = @_;

	return $self->datetime->strftime('%d.%m.%Y');
}

sub time {
	my ($self) = @_;

	return $self->datetime->strftime('%H:%M:%S');
}

sub route_timetable {
	my ($self) = @_;

	return @{ $self->{route_timetable} };
}

sub TO_JSON {
	my ($self) = @_;

	return { %{$self} };
}

1;

__END__

=head1 NAME

Travel::Status::DE::URA::Result - Information about a single
departure received by Travel::Status::DE::URA

=head1 SYNOPSIS

    for my $departure ($status->results) {
        printf(
            "At %s: %s to %s (in %d minutes)",
            $departure->time, $departure->line, $departure->destination,
            $departure->countdown
        );
    }

=head1 VERSION

version 0.03

=head1 DESCRIPTION

Travel::Status::DE::URA::Result describes a single departure as obtained by
Travel::Status::DE::URA.  It contains information about the time,
line number and destination.

=head1 METHODS

=head2 ACCESSORS

=over

=item $departure->countdown

Time in minutes from the time Travel::Status::DE::URA was instantiated until
the bus will depart.

=item $departure->countdown_sec

Time in seconds from the time Travel::Status::DE::URA was instantiated until
the bus will depart.

=item $departure->date

Departure date (DD.MM.YYYY)

=item $departure->datetime

DateTime object holding the departure date and time.

=item $departure->destination

Destination name.

=item $departure->line

The name of the line.

=item $departure->line_id

The number of the line.

=item $departure->route_timetable

If the B<results> method of Travel::Status::DE::URA(3pm) was called with
B<full_routes> => true:
Returns a list of arrayrefs describing the entire route. I.e.
C<< [[$time1, $stop1], [$time2, $stop2], ...] >>.
The times are DateTime::Duration(3pm) objects, the stops are only names,
not IDs (subject to change).  Returns an empty list otherwise.

=item $departure->stop

The stop belonging to this departure.

=item $departure->stop_id

The stop ID belonging to this departure.

=item $departure->time

Departure time (HH:MM:SS).

=back

=head2 INTERNAL

=over

=item $departure = Travel::Status::DE::URA::Result->new(I<%data>)

Returns a new Travel::Status::DE::URA::Result object.  You should not need to
call this.

=item $departure->TO_JSON

Allows the object data to be serialized to JSON.

=back

=head1 DIAGNOSTICS

None.

=head1 DEPENDENCIES

=over

=item Class::Accessor(3pm)

=back

=head1 BUGS AND LIMITATIONS

Unknown.

=head1 SEE ALSO

Travel::Status::DE::URA(3pm).

=head1 AUTHOR

Copyright (C) 2013 by Daniel Friesel E<lt>derf@finalrewind.orgE<gt>

=head1 LICENSE

This module is licensed under the same terms as Perl itself.