From a9b5a18943c3e2070703e745cd1131a02fd20365 Mon Sep 17 00:00:00 2001
From: Birte Kristina Friesel <derf@finalrewind.org>
Date: Sun, 23 Mar 2025 18:07:50 +0100
Subject: Preliminary DBRIS support (not user-accessible yet)

working:
* checkin
* checkout
* realtime data
* polylines
* carriage formation (long-distance only)

to do:
* geolocation
* redirects after checkout / undo
* traewelling sync
* use dbris by default
---
 lib/Travelynx/Helper/DBRIS.pm | 138 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 138 insertions(+)
 create mode 100644 lib/Travelynx/Helper/DBRIS.pm

(limited to 'lib/Travelynx/Helper/DBRIS.pm')

diff --git a/lib/Travelynx/Helper/DBRIS.pm b/lib/Travelynx/Helper/DBRIS.pm
new file mode 100644
index 0000000..e647cc5
--- /dev/null
+++ b/lib/Travelynx/Helper/DBRIS.pm
@@ -0,0 +1,138 @@
+package Travelynx::Helper::DBRIS;
+
+# Copyright (C) 2025 Birte Kristina Friesel
+#
+# SPDX-License-Identifier: AGPL-3.0-or-later
+
+use strict;
+use warnings;
+use 5.020;
+use utf8;
+
+use DateTime;
+use Encode qw(decode);
+use JSON;
+use Mojo::Promise;
+use Mojo::UserAgent;
+use Travel::Status::DE::DBRIS;
+
+sub new {
+	my ( $class, %opt ) = @_;
+
+	my $version = $opt{version};
+
+	$opt{header}
+	  = { 'User-Agent' =>
+"travelynx/${version} on $opt{root_url} +https://finalrewind.org/projects/travelynx"
+	  };
+
+	return bless( \%opt, $class );
+}
+
+sub get_station_id_p {
+	my ( $self, $station_name ) = @_;
+	my $promise = Mojo::Promise->new;
+	Travel::Status::DE::DBRIS->new_p(
+		locationSearch => $station_name,
+		cache          => $self->{cache},
+		lwp_options    => {
+			timeout => 10,
+			agent   => $self->{header}{'User-Agent'},
+		},
+		promise    => 'Mojo::Promise',
+		user_agent => Mojo::UserAgent->new,
+	)->then(
+		sub {
+			my ($dbris) = @_;
+			my $found;
+			for my $result ( $dbris->results ) {
+				if ( defined $result->eva ) {
+					$promise->resolve($result);
+					return;
+				}
+			}
+			$promise->reject("Unable to find station '$station_name'");
+			return;
+		}
+	)->catch(
+		sub {
+			my ($err) = @_;
+			$promise->reject("'$err' while trying to look up '$station_name'");
+			return;
+		}
+	)->wait;
+	return $promise;
+}
+
+sub get_departures_p {
+	my ( $self, %opt ) = @_;
+
+	my $agent = $self->{user_agent};
+
+	if ( $opt{station} =~ m{ [@] L = (?<eva> \d+ ) [@] }x ) {
+		$opt{station} = {
+			eva => $+{eva},
+			id  => $opt{station},
+		};
+	}
+
+	my $when = (
+		  $opt{timestamp}
+		? $opt{timestamp}->clone
+		: DateTime->now( time_zone => 'Europe/Berlin' )
+	)->subtract( minutes => $opt{lookbehind} );
+	return Travel::Status::DE::DBRIS->new_p(
+		station    => $opt{station},
+		datetime   => $when,
+		cache      => $self->{cache},
+		promise    => 'Mojo::Promise',
+		user_agent => $agent->request_timeout(10),
+	);
+}
+
+sub get_journey_p {
+	my ( $self, %opt ) = @_;
+
+	my $promise = Mojo::Promise->new;
+	my $now     = DateTime->now( time_zone => 'Europe/Berlin' );
+
+	my $agent = $self->{user_agent};
+	if ( my $proxy = $self->{service_config}{dbris}{proxy} ) {
+		$agent = Mojo::UserAgent->new;
+		$agent->proxy->http($proxy);
+		$agent->proxy->https($proxy);
+	}
+
+	Travel::Status::DE::DBRIS->new_p(
+		journey       => $opt{trip_id},
+		with_polyline => $opt{with_polyline},
+		cache         => $self->{realtime_cache},
+		promise       => 'Mojo::Promise',
+		user_agent    => $agent->request_timeout(10),
+	)->then(
+		sub {
+			my ($dbris) = @_;
+			my $journey = $dbris->result;
+
+			if ($journey) {
+				$self->{log}->debug("get_journey_p($opt{trip_id}): success");
+				$promise->resolve($journey);
+				return;
+			}
+			$self->{log}->debug("get_journey_p($opt{trip_id}): no journey");
+			$promise->reject('no journey');
+			return;
+		}
+	)->catch(
+		sub {
+			my ($err) = @_;
+			$self->{log}->debug("get_journey_p($opt{trip_id}): error $err");
+			$promise->reject($err);
+			return;
+		}
+	)->wait;
+
+	return $promise;
+}
+
+1;
-- 
cgit v1.2.3


From dce193201beb3621cfae1a799de446e083a7e2f6 Mon Sep 17 00:00:00 2001
From: Birte Kristina Friesel <derf@finalrewind.org>
Date: Thu, 10 Apr 2025 21:47:04 +0200
Subject: dbris: get_journey_p: respect proxy config

---
 lib/Travelynx/Helper/DBRIS.pm | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

(limited to 'lib/Travelynx/Helper/DBRIS.pm')

diff --git a/lib/Travelynx/Helper/DBRIS.pm b/lib/Travelynx/Helper/DBRIS.pm
index e647cc5..80c9c03 100644
--- a/lib/Travelynx/Helper/DBRIS.pm
+++ b/lib/Travelynx/Helper/DBRIS.pm
@@ -97,7 +97,7 @@ sub get_journey_p {
 	my $now     = DateTime->now( time_zone => 'Europe/Berlin' );
 
 	my $agent = $self->{user_agent};
-	if ( my $proxy = $self->{service_config}{dbris}{proxy} ) {
+	if ( my $proxy = $self->{service_config}{'bahn.de'}{proxy} ) {
 		$agent = Mojo::UserAgent->new;
 		$agent->proxy->http($proxy);
 		$agent->proxy->https($proxy);
-- 
cgit v1.2.3


From 4bc9bdcae3f990e9ad7c30bc5b9b7fd4ce2ca787 Mon Sep 17 00:00:00 2001
From: Birte Kristina Friesel <derf@finalrewind.org>
Date: Sun, 8 Jun 2025 08:58:32 +0200
Subject: DBRIS: Support multiple proxies

---
 lib/Travelynx/Helper/DBRIS.pm | 11 ++++++++++-
 1 file changed, 10 insertions(+), 1 deletion(-)

(limited to 'lib/Travelynx/Helper/DBRIS.pm')

diff --git a/lib/Travelynx/Helper/DBRIS.pm b/lib/Travelynx/Helper/DBRIS.pm
index 80c9c03..0a46758 100644
--- a/lib/Travelynx/Helper/DBRIS.pm
+++ b/lib/Travelynx/Helper/DBRIS.pm
@@ -97,7 +97,16 @@ sub get_journey_p {
 	my $now     = DateTime->now( time_zone => 'Europe/Berlin' );
 
 	my $agent = $self->{user_agent};
-	if ( my $proxy = $self->{service_config}{'bahn.de'}{proxy} ) {
+	my $proxy;
+	if ( my @proxies = @{ $self->{service_config}{'bahn.de'}{proxies} // [] } )
+	{
+		$proxy = $proxies[ int( rand( scalar @proxies ) ) ];
+	}
+	elsif ( my $p = $self->{service_config}{'bahn.de'}{proxy} ) {
+		$proxy = $p;
+	}
+
+	if ($proxy) {
 		$agent = Mojo::UserAgent->new;
 		$agent->proxy->http($proxy);
 		$agent->proxy->https($proxy);
-- 
cgit v1.2.3