1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
|
package Travel::Status::DE::HAFAS::Stop;
# vim:foldmethod=marker
use strict;
use warnings;
use 5.014;
use parent 'Class::Accessor';
our $VERSION = '4.19';
Travel::Status::DE::HAFAS::Stop->mk_ro_accessors(
qw(loc
rt_arr sched_arr arr arr_delay arr_cancelled
rt_dep sched_dep dep dep_delay dep_cancelled
delay direction
rt_platform sched_platform platform is_changed_platform
load
)
);
# {{{ Constructor
sub new {
my ( $obj, %opt ) = @_;
my $ref = {
loc => $opt{loc},
};
bless( $ref, $obj );
$ref->parse_stop( $opt{stop}, $opt{common}, $opt{date},
$opt{datetime_ref}, $opt{strp_obj} );
return $ref;
}
sub parse_stop {
my ( $self, $stop, $common, $date, $datetime_ref, $strp_obj ) = @_;
my $sched_arr = $stop->{aTimeS};
my $rt_arr = $stop->{aTimeR};
my $sched_dep = $stop->{dTimeS};
my $rt_dep = $stop->{dTimeR};
# dIn. / aOut. -> may passengers enter / exit the train?
my $sched_platform = $stop->{aPlatfS} // $stop->{dPlatfS};
my $rt_platform = $stop->{aPlatfR} // $stop->{dPlatfR};
my $changed_platform = $stop->{aPlatfCh} // $stop->{dPlatfCh};
for my $timestr ( $sched_arr, $rt_arr, $sched_dep, $rt_dep ) {
if ( not defined $timestr ) {
next;
}
$timestr = handle_day_change(
input => $timestr,
date => $date,
strp_obj => $strp_obj,
ref => $datetime_ref
);
}
my $arr_delay
= ( $sched_arr and $rt_arr )
? ( $rt_arr->epoch - $sched_arr->epoch ) / 60
: undef;
my $dep_delay
= ( $sched_dep and $rt_dep )
? ( $rt_dep->epoch - $sched_dep->epoch ) / 60
: undef;
my $arr_cancelled = $stop->{aCncl};
my $dep_cancelled = $stop->{dCncl};
my $tco = {};
for my $tco_id ( @{ $stop->{dTrnCmpSX}{tcocX} // [] } ) {
my $tco_kv = $common->{tcocL}[$tco_id];
$tco->{ $tco_kv->{c} } = $tco_kv->{r};
}
$self->{sched_arr} = $sched_arr;
$self->{rt_arr} = $rt_arr;
$self->{arr} = $rt_arr // $sched_arr;
$self->{arr_delay} = $arr_delay;
$self->{arr_cancelled} = $arr_cancelled;
$self->{sched_dep} = $sched_dep;
$self->{rt_dep} = $rt_dep;
$self->{dep} = $rt_dep // $sched_dep;
$self->{dep_delay} = $dep_delay;
$self->{dep_cancelled} = $dep_cancelled;
$self->{delay} = $dep_delay // $arr_delay;
$self->{direction} = $stop->{dDirTxt};
$self->{sched_platform} = $sched_platform;
$self->{rt_platform} = $rt_platform;
$self->{is_changed_platform} = $changed_platform;
$self->{platform} = $rt_platform // $sched_platform;
$self->{load} = $tco;
}
# }}}
sub handle_day_change {
my (%opt) = @_;
my $date = $opt{date};
my $timestr = $opt{input};
if ( length($timestr) == 8 ) {
# arrival time includes a day offset
my $offset_date = $opt{ref}->clone;
$offset_date->add( days => substr( $timestr, 0, 2, q{} ) );
$offset_date = $offset_date->strftime('%Y%m%d');
$timestr = $opt{strp_obj}->parse_datetime("${offset_date}T${timestr}");
}
else {
$timestr = $opt{strp_obj}->parse_datetime("${date}T${timestr}");
}
return $timestr;
}
sub TO_JSON {
my ($self) = @_;
my $ret = { %{$self} };
for my $k ( keys %{$ret} ) {
if ( ref( $ret->{$k} ) eq 'DateTime' ) {
$ret->{$k} = $ret->{$k}->epoch;
}
}
return $ret;
}
1;
__END__
=head1 NAME
Travel::Status::DE::HAFAS::Stop - Information about a HAFAS stop.
=head1 SYNOPSIS
# in journey mode
for my $stop ($journey->route) {
printf(
%5s -> %5s %s\n",
$stop->arr ? $stop->arr->strftime('%H:%M') : '--:--',
$stop->dep ? $stop->dep->strftime('%H:%M') : '--:--',
$stop->loc->name
);
}
=head1 VERSION
version 4.19
=head1 DESCRIPTION
Travel::Status::DE::HAFAS::Stop describes a
Travel::Status::DE::HAFAS::Journey(3pm)'s stop at a given
Travel::Status::DE::HAFAS::Location(3pm) with arrival/departure time,
platform, etc.
=head1 METHODS
=head2 ACCESSORS
=over
=item $stop->loc
Travel::Status::DE::HAFAS::Location(3pm) dinstance describing stop name, EVA
ID, et cetera.
=item $stop->rt_arr
DateTime object for actual arrival.
=item $stop->sched_arr
DateTime object for scheduled arrival.
=item $stop->arr
DateTime object for actual or scheduled arrival.
=item $stop->arr_delay
Arrival delay in minutes.
=item $stop->arr_cancelled
Arrival is cancelled.
=item $stop->rt_dep
DateTime object for actual departure.
=item $stop->sched_dep
DateTime object for scheduled departure.
=item $stop->dep
DateTIme object for actual or scheduled departure.
=item $stop->dep_delay
Departure delay in minutes.
=item $stop->dep_cancelled
Departure is cancelled.
=item $stop->delay
Departure or arrival delay in minutes.
=item $stop->direction
Direction signage from this stop on, undef if unchanged.
=item $stop->rt_platform
Actual platform.
=item $stop->sched_platform
Scheduled platform.
=item $stop->platform
Actual or scheduled platform.
=item $stop->is_changed_platform
True if real-time and scheduled platform disagree.
=item $stop->load
Expected utilization / passenger load from this stop on.
=back
=head1 DIAGNOSTICS
None.
=head1 DEPENDENCIES
=over
=item Class::Accessor(3pm)
=back
=head1 BUGS AND LIMITATIONS
None known.
=head1 SEE ALSO
Travel::Status::DE::HAFAS(3pm).
=head1 AUTHOR
Copyright (C) 2023 by Birte Kristina Friesel E<lt>derf@finalrewind.orgE<gt>
=head1 LICENSE
This module is licensed under the same terms as Perl itself.
|
