1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
|
package Travel::Status::DE::IRIS::Result;
use strict;
use warnings;
use 5.010;
no if $] >= 5.018, warnings => "experimental::smartmatch";
use parent 'Class::Accessor';
use Carp qw(cluck);
use DateTime;
use DateTime::Format::Strptime;
our $VERSION = '0.00';
Travel::Status::DE::IRIS::Result->mk_ro_accessors(
qw(arrival_date arrival_datetime arrival_time date datetime
departure_date departure_datetime departure_time line_no raw_id
start_date start_datetime start_time stop_no
time train_id train_no
type unknown_t unknown_o)
);
sub new {
my ( $obj, %opt ) = @_;
my $ref = \%opt;
my $strp = DateTime::Format::Strptime->new(
pattern => '%y%m%d%H%M',
time_zone => 'Europe/Berlin',
);
my ( $train_id, $start_ts, $stop_no ) = split( /.\K-/, $opt{raw_id} );
$ref->{start_datetime} = $strp->parse_datetime($start_ts);
$ref->{start_date} = $ref->{start_datetime}->strftime('%d.%m.%Y');
$ref->{start_time} = $ref->{start_datetime}->strftime('%H:%M');
$ref->{train_id} = $train_id;
$ref->{stop_no} = $stop_no;
$ref->{arrival_datetime} = $strp->parse_datetime( $opt{arrival_ts} );
$ref->{departure_datetime} = $strp->parse_datetime( $opt{departure_ts} );
if ( not( $ref->{arrival_datetime} or $ref->{departure_datetime} ) ) {
cluck(
sprintf(
"Neither '%s' nor '%s' are valid timestamps",
$opt{arrival_ts}, $opt{departure_ts}
)
);
}
if ( $ref->{arrival_datetime} ) {
my $dt = $ref->{datetime} = $ref->{arrival_datetime};
$ref->{arrival_date} = $ref->{date} = $dt->strftime('%d.%m.%Y');
$ref->{arrival_time} = $ref->{time} = $dt->strftime('%H:%M');
}
if ( $ref->{departure_datetime} ) {
my $dt = $ref->{datetime} = $ref->{departure_datetime};
$ref->{departure_date} = $ref->{date} = $dt->strftime('%d.%m.%Y');
$ref->{departure_time} = $ref->{time} = $dt->strftime('%H:%M');
}
return bless( $ref, $obj );
}
sub destination {
my ($self) = @_;
return $self->{route_end};
}
sub line {
my ($self) = @_;
return $self->{train};
}
sub origin {
my ($self) = @_;
return $self->{route_end};
}
sub route_interesting {
my ( $self, $max_parts ) = @_;
my @via = $self->route;
my ( @via_main, @via_show, $last_stop );
$max_parts //= 3;
for my $stop (@via) {
if ( $stop =~ m{ ?Hbf}o ) {
push( @via_main, $stop );
}
}
$last_stop = pop(@via);
if ( @via_main and $via_main[-1] eq $last_stop ) {
pop(@via_main);
}
if ( @via_main and @via and $via[0] eq $via_main[0] ) {
shift(@via_main);
}
if ( @via < $max_parts ) {
@via_show = @via;
}
else {
if ( @via_main >= $max_parts ) {
@via_show = ( $via[0] );
}
else {
@via_show = splice( @via, 0, $max_parts - @via_main );
}
while ( @via_show < $max_parts and @via_main ) {
my $stop = shift(@via_main);
if ( $stop ~~ \@via_show or $stop eq $last_stop ) {
next;
}
push( @via_show, $stop );
}
}
for (@via_show) {
s{ ?Hbf}{};
}
return @via_show;
}
sub route_timetable {
my ($self) = @_;
return @{ $self->{route} };
}
sub TO_JSON {
my ($self) = @_;
return { %{$self} };
}
1;
__END__
=head1 NAME
Travel::Status::DE::IRIS::Result - Information about a single
arrival/departure received by Travel::Status::DE::IRIS
=head1 SYNOPSIS
for my $departure ($status->results) {
printf(
"At %s: %s to %s from platform %s\n",
$departure->time,
$departure->line,
$departure->destination,
$departure->platform,
);
}
# or (depending on module setup)
for my $arrival ($status->results) {
printf(
"At %s: %s from %s on platform %s\n",
$arrival->time,
$arrival->line,
$arrival->origin,
$arrival->platform,
);
}
=head1 VERSION
version 1.02
=head1 DESCRIPTION
Travel::Status::DE::IRIs::Result describes a single arrival/departure
as obtained by Travel::Status::DE::IRIS. It contains information about
the platform, time, route and more.
=head1 METHODS
=head2 ACCESSORS
=over
=item $result->arrival_date
=item $result->arrival_datetime
=item $result->arrival_time
=item $result->date
=item $result->datetime
=item $result->departure_date
=item $result->departure_datetime
=item $result->departure_time
=item $result->line_no
=item $result->raw_id
=item $result->start_date
=item $result->start_datetime
=item $result->start_time
=item $result->stop_no
=item $result->time
=item $result->train_id
=item $result->train_no
=item $result->type
=item $result->unknown_t
=item $result->unknown_o
=back
=head2 INTERNAL
=over
=item $result = Travel::Status::DE::IRIS::Result->new(I<%data>)
Returns a new Travel::Status::DE::IRIS::Result object.
You usually do not need to call this.
=back
=head1 DIAGNOSTICS
None.
=head1 DEPENDENCIES
=over
=item Class::Accessor(3pm)
=back
=head1 BUGS AND LIMITATIONS
None known.
=head1 SEE ALSO
Travel::Status::DE::IRIS(3pm).
=head1 AUTHOR
Copyright (C) 2013 by Daniel Friesel E<lt>derf@finalrewind.orgE<gt>
=head1 LICENSE
This module is licensed under the same terms as Perl itself.
|
