1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
|
package App::Raps2::Password;
use strict;
use warnings;
use 5.010;
use Carp 'confess';
use Crypt::CBC;
use Crypt::Eksblowfish;
use Crypt::Eksblowfish::Bcrypt qw(bcrypt_hash en_base64 de_base64);
our $VERSION = '0.52';
sub new {
my ( $obj, %conf ) = @_;
$conf{cost} //= 12;
if ( not defined $conf{salt} ) {
$conf{salt} = create_salt();
}
if ( length( $conf{salt} ) != 16 ) {
confess('incorrect salt length');
}
if ( not( defined $conf{passphrase} and length $conf{passphrase} ) ) {
confess('no passphrase given');
}
my $ref = \%conf;
return bless( $ref, $obj );
}
sub create_salt {
my ($self) = @_;
my $salt = q{};
for ( 1 .. 16 ) {
$salt .= chr( 0x21 + int( rand(90) ) );
}
return $salt;
}
sub salt {
my ( $self, $salt ) = @_;
if ( defined $salt ) {
if ( length($salt) != 16 ) {
confess('incorrect salt length');
}
$self->{salt} = $salt;
}
return $self->{salt};
}
sub encrypt {
my ( $self, %opt ) = @_;
$opt{salt} //= $self->{salt};
$opt{cost} //= $self->{cost};
my $eksblowfish
= Crypt::Eksblowfish->new( $opt{cost}, $opt{salt}, $self->{passphrase}, );
my $cbc = Crypt::CBC->new( -cipher => $eksblowfish );
return $cbc->encrypt_hex( $opt{data} );
}
sub decrypt {
my ( $self, %opt ) = @_;
$opt{cost} //= $self->{cost};
$opt{salt} //= $self->{salt};
my $eksblowfish
= Crypt::Eksblowfish->new( $opt{cost}, $opt{salt}, $self->{passphrase}, );
my $cbc = Crypt::CBC->new( -cipher => $eksblowfish );
return $cbc->decrypt_hex( $opt{data} );
}
sub bcrypt {
my ($self) = @_;
return en_base64(
bcrypt_hash(
{
key_nul => 1,
cost => $self->{cost},
salt => $self->{salt},
},
$self->{passphrase},
)
);
}
sub verify {
my ( $self, $testhash ) = @_;
my $myhash = $self->bcrypt();
if ( $testhash eq $myhash ) {
return 1;
}
confess('Passwords did not match');
}
1;
__END__
=head1 NAME
App::Raps2::Password - Password class for App::Raps2
=head1 SYNOPSIS
use App::Raps2::Password;
my $pass = App::Raps2::Password->new(
passphrase => 'secret',
);
my $oneway_hash = $raps2->bcrypt();
$raps2->verify($oneway_hash);
my $twoway_hash = $raps2->encrypt('data');
print $raps2->decrypt($twoway_hash);
# "data"
=head1 VERSION
This manual documents B<App::Raps2::Password> version 0.52
=head1 DESCRIPTION
App::Raps2::Pasword is a wrapper around Crypt::Eksblowfish.
=head1 METHODS
=over
=item $pass = App::Raps2::Password->new(I<%conf>)
Creates a new I<App::Raps2::Password> object. You can only have one passphrase
per object. Arguments:
=over
=item B<cost> => I<int>
Cost to pass to B<Crypt::Eksblowfish>, defaults to 12.
=item B<passphrase> => I<string>
Passphrase to operate with. Mandatory.
=item B<salt> => I<string>
16-byte string to use as salt. If none is specified, B<App::Raps2::Password>
generates its own.
=back
=item $pass->create_salt()
Returns a new 16-byte salt. Contains only printable characters.
=item $pass->salt([I<salt>])
Returns the currently used salt and optionally changes it to I<salt>.
=item $pass->encrypt(B<data> => I<data>, [B<salt> => I<salt>],
[B<cost> => I<cost>])
Encrypts I<data> with the passphrase saved in the object, returns the
corresponding hexadecimal hash (as string).
By default, the salt set in B<salt> or B<new> will be used. You can override
it by specifying I<salt>.
=item $pass->decrypt(B<data> => I<hexstr>, [B<salt> => I<salt>],
[B<cost> => I<cost>])
Decrypts I<hexstr> (as created by B<encrypt>), returns its original content.
By default, the salt set in B<salt> or B<new> will be used. You can override
it by specifying I<salt>.
=item $pass->bcrypt()
Return a base64 bcrypt hash of the password, salted with the salt.
=item $pass->verify(I<hash>)
Verify a hash as returned by B<crypt>.
Returns true if it matches, dies if it doesn't.
=back
=head1 DIAGNOSTICS
When anything goes wrong, App::Raps2::Password will use Carp(3pm)'s B<confess>
method to die with a backtrace.
=head1 DEPENDENCIES
Crypt::CBC(3pm), Crypt::Eksblowfish(3pm).
=head1 BUGS AND LIMITATIONS
Unknown.
=head1 SEE ALSO
Crypt::CBC(3pm), Crypt::Eksblowfish(3pm).
=head1 AUTHOR
Copyright (C) 2011 by Daniel Friesel E<lt>derf@finalrewind.orgE<gt>
=head1 LICENSE
0. You just DO WHAT THE FUCK YOU WANT TO.
|
