1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
package Travel::Routing::DE::DBRIS::Connection;
use strict;
use warnings;
use 5.020;
use utf8;
use parent 'Class::Accessor';
use DateTime::Duration;
use Travel::Routing::DE::DBRIS::Connection::Segment;
our $VERSION = '0.04';
Travel::Routing::DE::DBRIS::Connection->mk_ro_accessors(
qw(changes feasibility is_cancelled is_unscheduled is_unlikely
duration sched_duration rt_duration
sched_dep rt_dep dep
sched_arr rt_arr arr
occupancy occupancy_first occupancy_second
price price_unit recon
)
);
sub new {
my ( $obj, %opt ) = @_;
my $json = $opt{json};
my $strpdate = $opt{strpdate_obj};
my $strptime = $opt{strptime_obj};
my $ref = {
changes => $json->{umstiegsAnzahl},
feasibility => $json->{ereignisZusammenfassung}{anschlussBewertungCode}
// -1,
is_unscheduled => $json->{isAlternativeVerbindung},
id => $json->{tripId},
recon => $json->{ctxRecon},
price => $json->{angebotsPreis}{betrag},
price_unit => $json->{angebotsPreis}{waehrung},
strptime_obj => $strptime,
};
if ( $ref->{price_unit} and $ref->{price_unit} eq 'EUR' ) {
$ref->{price_unit} = '€';
}
if ( my $d = $json->{verbindungsDauerInSeconds} ) {
$ref->{sched_duration} = DateTime::Duration->new(
hours => int( $d / 3600 ),
minutes => int( ( $d % 3600 ) / 60 ),
seconds => $d % 60,
);
}
if ( my $d = $json->{ezVerbindungsDauerInSeconds} ) {
$ref->{rt_duration} = DateTime::Duration->new(
hours => int( $d / 3600 ),
minutes => int( ( $d % 3600 ) / 60 ),
seconds => $d % 60,
);
}
$ref->{duration} = $ref->{rt_duration} // $ref->{sched_duration};
for my $occupancy ( @{ $json->{auslastungsmeldungen} // [] } ) {
if ( $occupancy->{klasse} eq 'KLASSE_1' ) {
$ref->{occupancy_first} = $occupancy->{stufe};
}
if ( $occupancy->{klasse} eq 'KLASSE_2' ) {
$ref->{occupancy_second} = $occupancy->{stufe};
}
}
if ( $ref->{occupancy_first} and $ref->{occupancy_second} ) {
$ref->{occupancy}
= ( $ref->{occupancy_first} + $ref->{occupancy_second} ) / 2;
}
elsif ( $ref->{occupancy_first} ) {
$ref->{occupancy} = $ref->{occupancy_first};
}
elsif ( $ref->{occupancy_second} ) {
$ref->{occupancy} = $ref->{occupancy_second};
}
for my $segment ( @{ $json->{verbindungsAbschnitte} // [] } ) {
push(
@{ $ref->{segments} },
Travel::Routing::DE::DBRIS::Connection::Segment->new(
json => $segment,
strptime_obj => $strptime
)
);
}
for my $i ( 0 .. $#{ $ref->{segments} // [] } - 1 ) {
if ( $ref->{segments}[$i]{train_short} ) {
my $arr = $ref->{segments}[$i]->arr;
for my $j ( $i + 1 .. $#{ $ref->{segments} // [] } ) {
if ( $ref->{segments}[$j]{train_short} ) {
my $dep = $ref->{segments}[$j]->dep;
if ( $arr and $dep ) {
$ref->{segments}[$j]{transfer_duration} = $dep - $arr;
if ( $dep < $arr ) {
$ref->{segments}[$i]{is_unlikely} = 1;
}
}
last;
}
}
}
}
for my $key (qw(sched_dep rt_dep dep)) {
$ref->{$key} = $ref->{segments}[0]{$key};
}
for my $key (qw(sched_arr rt_arr arr)) {
$ref->{$key} = $ref->{segments}[-1]{$key};
}
for my $note ( @{ $json->{risNotizen} // [] } ) {
push( @{ $ref->{notes} }, $note );
if ( $note->{key} eq 'text.realtime.connection.cancelled' ) {
$ref->{is_cancelled} = 1;
}
elsif ( $note->{key} eq 'text.realtime.connection.brokentrip' ) {
$ref->{is_unlikely} = 1;
}
}
for my $message ( @{ $json->{messages} // [] } ) {
push( @{ $ref->{messages} }, $message );
}
bless( $ref, $obj );
return $ref;
}
sub segments {
my ($self) = @_;
return @{ $self->{segments} // [] };
}
sub notes {
my ($self) = @_;
return @{ $self->{notes} // [] };
}
sub messages {
my ($self) = @_;
return @{ $self->{messages} // [] };
}
sub TO_JSON {
my ($self) = @_;
my $ret = { %{$self} };
delete $ret->{strptime_obj};
for my $k (qw(sched_dep rt_dep dep sched_arr rt_arr arr)) {
if ( $ret->{$k} ) {
$ret->{$k} = $ret->{$k}->epoch;
}
}
for my $k (qw(sched_duration rt_duration duration)) {
if ( $ret->{$k} ) {
$ret->{$k} = $ret->{$k}->in_units('minutes');
}
}
return $ret;
}
1;
|
