refactor (has|get)_wagonorder_p into DBRIS helper

1 files changed, 128 insertions, 2 deletions

diff --git a/lib/Travelynx/Helper/DBRIS.pm b/lib/Travelynx/Helper/DBRIS.pm
index 1eea830..966a78d 100644
--- a/lib/Travelynx/Helper/DBRIS.pm
+++ b/lib/Travelynx/Helper/DBRIS.pm
@@ -68,7 +68,7 @@ sub get_station_id_p {
 
 	Travel::Status::DE::DBRIS->new_p(
 		locationSearch => $station_name,
-		cache          => $self->{cache},
+		cache          => $self->{realtime_cache},
 		lwp_options    => {
 			timeout => 10,
 			agent   => $self->{header}{'User-Agent'},
@@ -117,7 +117,7 @@ sub get_departures_p {
 	return Travel::Status::DE::DBRIS->new_p(
 		station    => $opt{station},
 		datetime   => $when,
-		cache      => $self->{cache},
+		cache      => $self->{realtime_cache},
 		promise    => 'Mojo::Promise',
 		user_agent => $self->get_agent->request_timeout(10),
 	);
@@ -160,4 +160,130 @@ sub get_journey_p {
 	return $promise;
 }
 
+sub has_wagonorder_p {
+	my ( $self, %opt ) = @_;
+
+	$opt{train_type} //= q{};
+	my $datetime = $opt{datetime}->clone->set_time_zone('UTC');
+	my %param    = (
+		administrationId => 80,
+		category         => $opt{train_type},
+		date             => $datetime->strftime('%Y-%m-%d'),
+		evaNumber        => $opt{eva},
+		number           => $opt{train_no},
+		time             => $datetime->rfc3339 =~ s{(?=Z)}{.000}r
+	);
+
+	my $url = sprintf( '%s?%s',
+'https://www.bahn.de/web/api/reisebegleitung/wagenreihung/vehicle-sequence',
+		join( '&', map { $_ . '=' . $param{$_} } sort keys %param ) );
+
+	my $promise = Mojo::Promise->new;
+	my $debug_prefix
+	  = "has_wagonorder_p($opt{train_type} $opt{train_no} @ $opt{eva})";
+
+	if ( my $content = $self->{main_cache}->get("HEAD $url")
+		// $self->{realtime_cache}->get("HEAD $url") )
+	{
+		if ( $content eq 'n' ) {
+			$self->{log}->debug("${debug_prefix}: n (cached)");
+			return $promise->reject;
+		}
+		else {
+			$self->{log}->debug("${debug_prefix}: ${content} (cached)");
+			return $promise->resolve($content);
+		}
+	}
+
+	$self->get_agent->request_timeout(5)
+	  ->get_p( $url => $self->{header} )
+	  ->then(
+		sub {
+			my ($tx) = @_;
+			if ( $tx->result->is_success ) {
+				$self->{log}->debug("${debug_prefix}: a");
+				$self->{main_cache}->set( "HEAD $url", 'a' );
+				my $body = decode( 'utf-8', $tx->res->body );
+				my $json = JSON->new->decode($body);
+				$self->{main_cache}->freeze( $url, $json );
+				$promise->resolve('a');
+			}
+			else {
+				my $code = $tx->res->code;
+				$self->{log}->debug("${debug_prefix}: n (HTTP $code)");
+				$self->{realtime_cache}->set( "HEAD $url", 'n' );
+				$promise->reject;
+			}
+			return;
+		}
+	  )->catch(
+		sub {
+			my ($err) = @_;
+			$self->{log}->debug("${debug_prefix}: n ($err)");
+			$self->{realtime_cache}->set( "HEAD $url", 'n' );
+			$promise->reject;
+			return;
+		}
+	  )->wait;
+	return $promise;
+}
+
+sub get_wagonorder_p {
+	my ( $self, %opt ) = @_;
+
+	my $datetime = $opt{datetime}->clone->set_time_zone('UTC');
+	my %param    = (
+		administrationId => 80,
+		category         => $opt{train_type},
+		date             => $datetime->strftime('%Y-%m-%d'),
+		evaNumber        => $opt{eva},
+		number           => $opt{train_no},
+		time             => $datetime->rfc3339 =~ s{(?=Z)}{.000}r
+	);
+
+	my $url = sprintf( '%s?%s',
+'https://www.bahn.de/web/api/reisebegleitung/wagenreihung/vehicle-sequence',
+		join( '&', map { $_ . '=' . $param{$_} } sort keys %param ) );
+	my $debug_prefix
+	  = "get_wagonorder_p($opt{train_type} $opt{train_no} @ $opt{eva})";
+
+	my $promise = Mojo::Promise->new;
+
+	if ( my $content = $self->{main_cache}->thaw($url) ) {
+		$self->{log}->debug("${debug_prefix}: (cached)");
+		$promise->resolve($content);
+		return $promise;
+	}
+
+	$self->get_agent->request_timeout(5)
+	  ->get_p( $url => $self->{header} )
+	  ->then(
+		sub {
+			my ($tx) = @_;
+
+			if ( $tx->result->is_success ) {
+				my $body = decode( 'utf-8', $tx->res->body );
+				my $json = JSON->new->decode($body);
+				$self->{log}->debug("${debug_prefix}: success");
+				$self->{main_cache}->freeze( $url, $json );
+				$promise->resolve($json);
+			}
+			else {
+				my $code = $tx->res->code;
+				$self->{log}->debug("${debug_prefix}: HTTP ${code}");
+				$promise->reject("HTTP ${code}");
+			}
+			return;
+		}
+	  )->catch(
+		sub {
+			my ($err) = @_;
+			$self->{log}->debug("${debug_prefix}: error ${err}");
+			$promise->reject($err);
+			return;
+		}
+	  )->wait;
+	return $promise;
+}
+
 1;