1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
package Travelynx::Helper::DBRIS;
# Copyright (C) 2025 Birte Kristina Friesel
#
# SPDX-License-Identifier: AGPL-3.0-or-later
use strict;
use warnings;
use 5.020;
use utf8;
use DateTime;
use Encode qw(decode);
use JSON;
use Mojo::Promise;
use Mojo::UserAgent;
use Travel::Status::DE::DBRIS;
sub new {
my ( $class, %opt ) = @_;
my $version = $opt{version};
$opt{header}
= { 'User-Agent' =>
"travelynx/${version} on $opt{root_url} +https://finalrewind.org/projects/travelynx"
};
return bless( \%opt, $class );
}
sub get_station_id_p {
my ( $self, $station_name ) = @_;
my $promise = Mojo::Promise->new;
Travel::Status::DE::DBRIS->new_p(
locationSearch => $station_name,
cache => $self->{cache},
lwp_options => {
timeout => 10,
agent => $self->{header}{'User-Agent'},
},
promise => 'Mojo::Promise',
user_agent => Mojo::UserAgent->new,
)->then(
sub {
my ($dbris) = @_;
my $found;
for my $result ( $dbris->results ) {
if ( defined $result->eva ) {
$promise->resolve($result);
return;
}
}
$promise->reject("Unable to find station '$station_name'");
return;
}
)->catch(
sub {
my ($err) = @_;
$promise->reject("'$err' while trying to look up '$station_name'");
return;
}
)->wait;
return $promise;
}
sub get_departures_p {
my ( $self, %opt ) = @_;
my $agent = $self->{user_agent};
if ( $opt{station} =~ m{ [@] L = (?<eva> \d+ ) [@] }x ) {
$opt{station} = {
eva => $+{eva},
id => $opt{station},
};
}
my $when = (
$opt{timestamp}
? $opt{timestamp}->clone
: DateTime->now( time_zone => 'Europe/Berlin' )
)->subtract( minutes => $opt{lookbehind} );
return Travel::Status::DE::DBRIS->new_p(
station => $opt{station},
datetime => $when,
cache => $self->{cache},
promise => 'Mojo::Promise',
user_agent => $agent->request_timeout(10),
);
}
sub get_journey_p {
my ( $self, %opt ) = @_;
my $promise = Mojo::Promise->new;
my $now = DateTime->now( time_zone => 'Europe/Berlin' );
my $agent = $self->{user_agent};
if ( my $proxy = $self->{service_config}{dbris}{proxy} ) {
$agent = Mojo::UserAgent->new;
$agent->proxy->http($proxy);
$agent->proxy->https($proxy);
}
Travel::Status::DE::DBRIS->new_p(
journey => $opt{trip_id},
with_polyline => $opt{with_polyline},
cache => $self->{realtime_cache},
promise => 'Mojo::Promise',
user_agent => $agent->request_timeout(10),
)->then(
sub {
my ($dbris) = @_;
my $journey = $dbris->result;
if ($journey) {
$self->{log}->debug("get_journey_p($opt{trip_id}): success");
$promise->resolve($journey);
return;
}
$self->{log}->debug("get_journey_p($opt{trip_id}): no journey");
$promise->reject('no journey');
return;
}
)->catch(
sub {
my ($err) = @_;
$self->{log}->debug("get_journey_p($opt{trip_id}): error $err");
$promise->reject($err);
return;
}
)->wait;
return $promise;
}
1;
|
