etc/completions/_fbsetbg


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

#compdef fbsetbg
## completion for fbsetbg (fluxbox 1.0.0+deb1-9), based on fbsetbg(1)
## Daniel Friesel <derf@derf.homelinux.org>
## License: WTFPL <http://sam.zoy.org/wtfpl>:
##   0. You just DO WHAT THE FUCK YOU WANT TO.
##
## http://derf.homelinux.org/git/zsh/plain/etc/completions/_fbsetbg

local -a arguments
local -A file_arguments

arguments=(
	'(-u)-U[specify wallpapersetter (without remembering)]:wallpapersetter: '
	'(-U)-u[specify wallpapersetter]:wallpapersetter: '
	'(-b)-B[options for fbsetroot (without remembering)]:fbsetroot options: '
	'(-B)-b[options for fbsetroot]:fbsetroot options: '
	- '(exclusive)'
	'-h[show help]'
	'-i[show wallpapersetter information]'
	'-l[set previous wallpaper]'
	'-p[show tips]'
	'-r[set random wallpaper from directory]:directory:_path_files -/'
	'-R[set random wallpaper from directory (without remembering)]:directory:_path_files -/'
)

file_arguments=(
	'-f' 'fullscreen'
	'-c' 'centered'
	'-t' 'tiled'
	'-a' 'fullscreen (preserving aspect)'
)

for arg in ${(k)file_arguments}; {
	arguments+=${arg}'[set '${file_arguments[$arg]}' wallpaper]:file:_files'
	arguments+=${arg:u}'[set '${file_arguments[$arg]}' wallpaper (without remembering)]:file:_files'
}

_arguments -s ${arguments}